ON ERROR IF ERR=17 CHAIN @lib$+"../examples/tools/touchide" ELSE MODE 3 : PRINT REPORT$ : END
      
      REM Spinning Carousel model from turbosquid.com
      REM MAY NOT BE REUSED WITHOUT BEING REPURCHASED
      
      SYS "SDL_SetWindowTitle", @hwnd%, "Thunder and Blazes (Entry of the Gladiators) by Julius Fučik", @memhdc%
      
      INSTALL @lib$+"webgllib"
      INSTALL @lib$+"gfxlib"
      PROC_gfxInit
      
      DIM Object%(3), nVert%(3), vFormat%(3), vSize%(3), Texture%(3), Light%(1)
      DIM Material%(3), Pan(3), Tilt(3), Roll(3), Xpos(3), Ypos(3), Zpos(3)
      DIM Q1&(3), Q2&(3), Q3&(3), Q4&(3)
      
      DIM Light{(1)Type%, Diffuse{r%,g%,b%,a%}, Specular{r%,g%,b%,a%}, \
      \ Ambient{r%,g%,b%,a%}, Position{x%,y%,z%}, Direction{x%,y%,z%}, \
      \ Range%, Falloff%, Attenuation0%, Attenuation1%, Attenuation2%, \
      \ Theta%, Phi%}
      
      PRINT "Please wait..."
      *REFRESH OFF
      *REFRESH
      
      t%% = FN_gfxLoadTextureSwapRGB(@dir$ + "horses.jpg", 0, 1)
      PROC_gfxPlotScale(t%%, 512, 512, 0, @size.y%-512)
      PROC_gfxDestroyTexture(t%%)
      OSCLI "GSAVE   """ + @tmp$ + "horses.bmp"" 0,0,1024,1024"
      CLS
      
      ON CLOSE PROCcleanup : QUIT
      ON ERROR PROCcleanup : IF ERR=17 CHAIN @lib$+"../examples/tools/touchide" ELSE MODE 3 : PRINT REPORT$ : END
      ON MOVE Resize% OR= (@msg% = 5) : RETURN
      
      Device% = 0
      Resize% = FALSE
      PROCinitrender
      
      *TEMPO 133
      *STEREO 1,127
      *STEREO 2,42
      *STEREO 3,-42
      *STEREO 0,-127
      *VOICE 0,6
      *VOICE 1,6
      *VOICE 2,6
      *VOICE 3,6
      SOUND 1,0,0,10
      
      DIM snd{(3,50)a&,p&,d&}, p%(3), q%(3), cli$(3)
      DIM cmajor&(7), scale%(7), acc%(7), flat&(7), sharp&(7)
      cmajor&() = 88,96,52,60,68,72,80
      flat&() = 0, &02, &12, &13, &1B, &5B, &5F, &7F
      sharp&() = 0, &A0, &A4, &E4, &EC, &ED, &FD, &FF
      dur% = 24
      tempo = 4
      ENVELOPE 1,1,0,0,0,0,0,0,64,0,0,-4,119,89
      REPEAT
        REPEAT
          READ R$ : IF R$="" REPEAT PROCanimate : UNTIL FALSE
          T$ += R$ : IF RIGHT$(T$) = "\" T$ = LEFT$(T$)
        UNTIL RIGHT$(R$) <> "\"
        acc%() = scale%()
        clef% = 48 : voice% = 1
        p%() = 0 : q%() = 0
        WHILE T$<>""
          I% = 1 : WHILE INSTR("0123456789",MID$(T$,I%,1)) I% += 1 : ENDWHILE
          IF I% > 1 dur% = VALLEFT$(T$,I%-1) : T$ = MID$(T$,I%)
          C$ = LEFT$(T$,1) : T$=MID$(T$,2)
          CASE C$ OF
            WHEN " ":
            WHEN ";": T$ = ""
            WHEN "[": T$ = ""
            WHEN "P": T$ = MID$(T$,2)
            WHEN "=": beat% = 0
              WHILE ASC(T$)>=&30 AND ASC(T$)<=&39 beat% = beat% * 10 + ASC(T$)-&30
                T$ = MID$(T$,2) : ENDWHILE
              WHILE ADVAL(-5)<16 OR ADVAL(-6)<16 OR ADVAL(-7)<16 OR ADVAL(-8)<16
                PROCanimate : ENDWHILE
              CASE TRUE OF
                WHEN beat% <= 60  tempo = 3 : *TEMPO 130
                WHEN beat% <= 70  tempo = 4 : *TEMPO 131
                WHEN beat% <= 100 tempo = 3 : *TEMPO 131
                WHEN beat% <= 120 tempo = 4 : *TEMPO 133
                WHEN beat% <= 130 tempo = 3 : *TEMPO 132
                WHEN beat% <= 150 tempo = 2 : *TEMPO 131
                WHEN beat% <= 170 tempo = 3 : *TEMPO 133
              ENDCASE
            WHEN "T": acc%() = scale%() : clef% = 48
            WHEN "S": acc%() = scale%() : clef% = 0
            WHEN "V": acc%() = scale%() : voice% = ASC(T$) - &30 : T$=MID$(T$,2)
              voice% AND= 3
            WHEN "W": wave% = VAL(T$) : T$ = MID$(T$,2)
              WHILE ADVAL(-5-voice%)<16 PROCanimate : ENDWHILE
              cli$(voice%) = "voice " + STR$voice% + "," + STR$(wave%)
            WHEN "K": key% = ASC(T$) - &30 : T$=MID$(T$,2)
              scale%() = 0
              IF key% THEN
                key$ = LEFT$(T$,1) : T$=MID$(T$,2)
                CASE key$ OF
                  WHEN "#": key& = sharp&(key%)
                  WHEN "b","&": key& = flat&(key%)
                ENDCASE
                FOR I% = 0 TO 6
                  IF key& AND (2^I%) scale%(I%) = -4 : IF key& AND &80 scale%(I%) = +4
                NEXT
              ENDIF
              acc%() = scale%()
            OTHERWISE
              Note% = INSTR("ABCDEFG$",C$)-1
              IF Note% < 0 ERROR 100, "Unrecognised command "+C$
              octave% = 0
              staccato = 0
              ticks% = dur% / tempo
              REPEAT
                CASE LEFT$(T$,1) OF
                  WHEN "#": acc%(Note%) = 4
                  WHEN "%": acc%(Note%) = 0
                  WHEN "&","b": acc%(Note%) =-4
                  WHEN "+": octave% += 48
                  WHEN "-": octave% -= 48
                  WHEN ".": ticks% = dur% / tempo * 3/2
                  WHEN ":": ticks% = dur% / tempo * 2/3
                  WHEN ",": staccato = 1/3
                  WHEN "'":  staccato = 1/6
                  WHEN """": staccato = 1/6
                  OTHERWISE: EXIT REPEAT
                ENDCASE
                T$=MID$(T$,2)
              UNTIL FALSE
              pitch% = cmajor&(Note%) + acc%(Note%) + clef% + octave%
              IF Note% = 7 pitch% = 0
              IF pitch% < 0 OR pitch% > 255 ERROR 100, "Pitch out of range: "+STR$pitch%
              IF ticks% < 0 OR ticks% > 254 ERROR 100, "Duration out of range: "+STR$ticks%
              gap% = INT(ticks% * staccato) + 0.5
              snd{(voice%,p%(voice%))}.p& = pitch%
              snd{(voice%,p%(voice%))}.d& = ticks% - gap%
              p%(voice%) += 1
              IF gap% THEN
                snd{(voice%,p%(voice%))}.p& = 0
                snd{(voice%,p%(voice%))}.d& = gap%
                p%(voice%) += 1
              ENDIF
          ENDCASE
        ENDWHILE
        WHILE ADVAL(-5)=0 OR ADVAL(-6)=0 OR ADVAL(-7)=0 OR ADVAL(-8)=0
          PROCanimate
        ENDWHILE
        IF p%(0)<>q%(0) OR p%(1)<>q%(1) OR p%(2)<>q%(2) OR p%(3)<>q%(3) THEN
          SOUND &300,0,0,0 : SOUND &301,0,0,0 : SOUND &302,0,0,0 : SOUND &303,0,0,0
          FOR v% = 0 TO 3
            IF cli$(v%)<>"" OSCLI(cli$(v%)) : cli$(v%) = ""
          NEXT
          REPEAT
            stall% = TRUE
            FOR v% = 0 TO 3
              IF q%(v%) < p%(v%) IF ADVAL(-5-v%) THEN
                stall% = FALSE
                IF snd{(v%,q%(v%))}.p& = 0 THEN
                  SOUND v%+&1000,1,0,snd{(v%,q%(v%))}.d&
                ELSE
                  SOUND v%,1,snd{(v%,q%(v%))}.p&,snd{(v%,q%(v%))}.d&
                ENDIF
                q%(v%) += 1
              ENDIF
            NEXT v%
            IF stall% PROCanimate
          UNTIL p%(0)=q%(0) AND p%(1)=q%(1) AND p%(2)=q%(2) AND p%(3)=q%(3)
        ENDIF
      UNTIL FALSE
      END
      
      DEF PROCanimate
      LOCAL bgcolour%, nobjects%, nlights%, viewangle, aspectratio, mindist, maxdist, cameraroll
      LOCAL camera(), lookat() : DIM camera(2), lookat(2)
      
      lookat() = 0, 3, 0
      bgcolour% = &FFC0C0D0
      nlights% = 2
      nobjects% = 4
      viewangle = PI/8
      aspectratio = @vdu%!208/@vdu%!212
      mindist = 5.0
      maxdist = 30.0
      cameraroll = 0
      Ypos(2) = 0.3 + 0.5 * SIN(TIME/100)
      Ypos(3) = 0.3 - 0.5 * SIN(TIME/100)
      Pan(0) = -0.3
      Pan(1) = -TIME/500
      Pan(2) = Pan(1)
      Pan(3) = Pan(2) + PI/3
      camera() = 0, 4, -35
      PROC_render(Device%, bgcolour%, nlights%, Light%(), nobjects%, Material%(), Texture%(), \
      \ Object%(), nVert%(), vFormat%(), vSize%(), Pan(), Tilt(), Roll(), Xpos(), Ypos(), Zpos(), \
      \ camera(), lookat(), viewangle, aspectratio, mindist, maxdist, cameraroll)
      
      IF Resize% Resize% = FALSE : PROCcleanup : PROCinitrender
      ENDPROC
      
      DEF PROCinitrender
      IF POS REM SDL thread sync
      VDU 26
      
      Device% = FN_initgl(@hwnd%, 0, 3)
      IF Device% = 0 ERROR 100, "Can't initialise 3D library"
      
      REM Load the 3D objects:
      Object%(0) = FN_load3d(Device%, @dir$+"platform.fvf", nVert%(0), vFormat%(0), vSize%(0))
      IF Object%(0) = 0 ERROR 100, "Can't load platform.fvf"
      
      Object%(1) = FN_load3d(Device%, @dir$+"carousel.fvf", nVert%(1), vFormat%(1), vSize%(1))
      IF Object%(1) = 0 ERROR 100, "Can't load carousel.fvf"
      
      Object%(2) = FN_load3d(Device%, @dir$+"horses.fvf", nVert%(2), vFormat%(2), vSize%(2))
      IF Object%(2) = 0 ERROR 100, "Can't load horses.fvf"
      
      Object%(3) = Object%(3) : nVert%(3) = nVert%(2) : vFormat%(3) = vFormat%(2) : vSize%(3) = vSize%(2)
      
      REM Load the textures:
      Texture%(1) = FN_loadtexture(Device%, @dir$ + "carousel.png")
      IF Texture%(1) = 0 ERROR 100, "Can't load carousel.png"
      
      Texture%(2) = FN_loadtexture(Device%, @dir$ + "horses.jpg")
      IF Texture%(2) = 0 ERROR 100, "Can't load horses.jpg"
      
      Texture%(3) = FN_loadtexture(Device%, @tmp$ + "horses.bmp")
      IF Texture%(3) = 0 ERROR 100, "Can't load horses.bmp"
      
      Texture%(0) = Texture%(1)
      
      REM. Point-source Light:
      Light{(0)}.Type% = 1              : REM. point source
      Light{(0)}.Ambient.r% = FN_f4(0.15)  : REM. ambient colour RGB
      Light{(0)}.Ambient.g% = FN_f4(0.15)
      Light{(0)}.Ambient.b% = FN_f4(0.15)
      Light{(0)}.Ambient.a% = FN_f4(1)
      Light{(0)}.Diffuse.r% = FN_f4(0.5)  : REM. diffuse colour RGB
      Light{(0)}.Diffuse.g% = FN_f4(0.5)
      Light{(0)}.Diffuse.b% = FN_f4(0.5)
      Light{(0)}.Diffuse.a% = FN_f4(1)
      Light{(0)}.Specular.r% = FN_f4(0.5) : REM. specular colour RGB
      Light{(0)}.Specular.g% = FN_f4(0.5)
      Light{(0)}.Specular.b% = FN_f4(0.5)
      Light{(0)}.Position.x% = FN_f4(30) : REM. position XYZ
      Light{(0)}.Position.y% = FN_f4(7)
      Light{(0)}.Position.z% = FN_f4(-50)
      Light{(0)}.Range% = FN_f4(60)     : REM. range
      Light{(0)}.Attenuation0% = FN_f4(1) : REM. attenuation (constant)
      Light%(0) = Light{(0)} - PAGE + !340
      
      Light{(1)} = Light{(0)}
      Light{(1)}.Position.x% = FN_f4(-30) : REM. position XYZ
      Light%(1) = Light{(1)} - PAGE + !340
      
      ENDPROC
      
      DEF PROCcleanup
      LOCAL I%
      FOR I% = 0 TO 2
        Object%(I%) += 0  : IF Object%(I%)  PROC_release(Object%(I%))  : Object%(I%) = 0
      NEXT
      FOR I% = 1 TO 3
        Texture%(I%) += 0 : IF Texture%(I%) PROC_release(Texture%(I%)) : Texture%(I%) = 0
      NEXT
      Device% += 0        : IF Device%      PROC_release(Device%)      : Device% = 0
      *REFRESH ON
      ENDPROC
      
      
      DATA "; THUNDER AND BLAZES , JULIUS FUCIK"
      DATA "; ENCODED BY LEON RUE, NOCCC, 9,16,77"
      DATA ";TRANSCODED BY R.T.RUSSELL"
      DATA ";Thunder and blazes - Julius Fucik."
      DATA "=110"
      
      DATA "; Intro (RTR 2023)"
      DATA "TV1 48E+.,12E+,E+, 48E+.,12E+,E+, V2 48E.,12E,E, 48E.,12E,E,"
      DATA "TV1 192E+ V2 192E SV3 12 E+$D+$C+$Bb$Ab$Gb$E%$D%$ V4 12 $E+b$D+b$B$A$G$F$Eb$C#"
      DATA "TV1 48F#+.,12F#+,F#+, 48F#+.,12F#+,F#+, V2 48F#.,12F#,F#, 48F#.,12F#,F#,"
      DATA "TV1 192F#+ V2 192F# SV3 12 F#+$E+$D+$C+$Bb$Ab$F#$E%$ V4 12 $F%+$E+b$Db+$B$A$G$F%$D#"
      DATA "TV1 48G+.,12G+,G+, V2 48G.,12G,G, SV3 8BF+BF+BF+BF+BF+BF+ V4 G$G$G$G$G$G$"
      DATA "TV1 48G+.,12G+,G+, V2 48G.,12G,G, SV3 8BF+BF+BF+BF+BF+BF+ V4 G$G$G$G$G$G$"
      DATA "TV1 12 GG#AA#BC+C+#D+         SV3 8BF+BF+BF+BF+BF+BF+ V4 G$G$G$G$G$G$"
      DATA "TV1 12 D+#E+F+F+#G+%G+#A+%B+% SV2 24G-F+,F+,F+, V3 $B,B,D+, V4 $G,G,G, "
      
      DATA "PA"
      DATA "T24C++,B+,12B+&,C++&,B+&,A+, V224CGG-G V3$E$E"
      DATA "T24A+&,G+,F+#G+, V224$G$G V3S24C+$G$"
      DATA "T24A+,A+&,12G+,A+,G+,F+#, V224$G$ V324CEG-E"
      DATA "T24F+,E+,D+#E+, V224$G$G V3S24C+$G"
      DATA "PB"
      DATA "T12G+,$F+,F+,24C+#D+, V224$G$G V3DFG-F"
      DATA "PC"
      DATA "T12G+,$F+,F+,24C+#D+, V224$G$G V3DFG-F"
      DATA "PD"
      DATA "T12BC+C+#D+D+#E+F+F+# V224$G$G V3SC+$G"
      DATA "T12G+G+#A+B+24A+G+% V224$G$G V3DFG-F"
      DATA "PE"
      DATA "T24C++,B+,12B+&,C++&,B+&,A+, V224CGG-G V3$E$E"
      DATA "T24A+&,G+,F+#G+, V224$G$G V3S24C+$G$"
      DATA "T24A+,A+&,12G+,A+,G+,F+#, V224$G$ V324CEG-E"
      DATA "T24F+,E+,D+#E+, V224$G$G V3S24C+$G"
      DATA "PG"
      DATA "T24D+#12D+,D+,24F+#B V224B12B,B, V3B-D#B-D"
      DATA "T12G+,A+,G+,F+#,24E+B+, V2EBEB V3$G$G"
      DATA "T24B+""12B+""B+""24B+""B+"" V2D+#""12D+""D+""24D+""D+"" V3S24B$B""B"""
      DATA "T24B+""$48B+ V224E+$48G+ V3S24E+$48G"
      DATA "PA"
      DATA "T24C++,B+,12B+&,C++&,B+&,A+, V224CGG-G V3$E$E"
      DATA "T24A+&,G+,F+#G+, V224$G$G V3S24C+$G$"
      DATA "T24A+,A+&,12G+,A+,G+,F+#, V224$G$ V324CEG-E"
      DATA "T24F+,E+,D+#E+, V224$G$G V3S24C+$G"
      DATA "PB"
      DATA "T12G+,$F+,F+,24C+#D+, V224$G$G V3DFG-F"
      DATA "PC"
      DATA "T12G+,$F+,F+,24C+#D+, V224$G$G V3DFG-F"
      DATA "PD"
      DATA "T12BC+C+#D+D+#E+F+F+# V224$G$G V3SC+$G"
      DATA "T12G+G+#A+B+24A+G+% V224$G$G V3DFG-F"
      DATA "PE"
      DATA "T24C++,B+,12B+&,C++&,B+&,A+, V224CGG-G V3$E$E"
      DATA "T24A+&,G+,F+#G+, V224$G$G V3S24C+$G$"
      DATA "T24A+,A+&,12G+,A+,G+,F+#, V224$G$ V324CEG-E"
      DATA "T24F+,E+,D+#E+, V224$G$G V3S24C+$G"
      DATA "PG"
      DATA "T24D+#12D+,D+,24F+#B V224B12B,B, V3B-D#B-D"
      DATA "T12G+,A+,G+,F+#,24E+B+, V2EBEB V3$G$G"
      DATA "T24B+""12B+""B+""24B+""B+"" V2D+#""12D+""D+""24D+""D+"" V3S24B$B""B"""
      DATA "T24B+""$48B+ V224E+$48G+ V3S24E+$48G"
      DATA "PH"
      DATA "T24$12G+,G+,24G+,G+, V3S48C.24G- V4S48C.24G-"
      DATA "T24$G+,$G+, V3S24C12B-CC#DD#E V4S24C12B-CC#DD#E"
      DATA "T24$12B,B,24B,B, V224$12G+,G+,24G+,G+, V3S48F.24E V4S48F.24E"
      DATA "T24$12B,B,24B,B, V224$12G+,G+,24G+,G+, V3S96D V4S96D"
      DATA "T24$12B,B,24B,B, V224$12G+,G+,24G+,G+, V3S48A.24G V4S48A.24G"
      DATA "T24$B$B V224$G+$G+ V3S12FGFEDEFD V4S12FGFEDEFD"
      DATA "T24$12G+,G+,24G+,G+, V224$12C+,C+,24C+,C+, V3S48C24CE V4S48C24CE"
      DATA "T24$12G+,G+,24G+,G+, V224$12C+,C+,24C+,C+, V3S96G- V4S96G-"
      DATA "T24$12G+,G+,24G+,G+, V224$12C+,C+,24C+,C+, V3S48C.24G- V4S48C.24G-"
      DATA "T24$G+,$G+, V224$C+,$C+, V3S24C12B-CDEFG V4S24C12B-CDEFG"
      DATA "T24$12A+,A+,24A+,A+, V224$12E+&,E+&,24E+&,E+&, V3S48F.24A- V4S48F.24A-"
      DATA "T24$12F+#,F+,24F+,F+, V224$12C+,C+,24C+,C+, V3S48C24B-C V4S48C24B-C"
      DATA "T24$12G+,G+,24$12G+,G+, V224$12C+,C+,24$12C+,C+, V3S48EC V4S48EC"
      DATA "T24$12G+,G+,24$12G+,G+, V224$12F+,F+,24$12F+,F+, V3S48FB V4S48FB"
      DATA "T24C++12B+,A+,G+,F+,E+,D+, V224E+ V3S24C12B,A,G,F,E,D, V4S24C12B,A,G,F,E,D,"
      DATA "PI"
      DATA "T24$12G+,G+,24G+,G+, V3S48C.24G- V4S48C.24G-"
      DATA "T24$G+,$G+, V3S24C12B-CC#DD#E V4S24C12B-CC#DD#E"
      DATA "T24$12B,B,24B,B, V224$12G+,G+,24G+,G+, V3S48F.24E V4S48F.24E"
      DATA "T24$12B,B,24B,B, V224$12G+,G+,24G+,G+, V3S96D V4S96D"
      DATA "T24$12B,B,24B,B, V224$12G+,G+,24G+,G+, V3S48A.24G V4S48A.24G"
      DATA "T24$B$B V224$G+$G+ V3S12FGFEDEFD V4S12FGFEDEFD"
      DATA "T24$12G+,G+,24G+,G+, V224$12C+,C+,24C+,C+, V3S48C24CE V4S48C24CE"
      DATA "T24$12G+,G+,24G+,G+, V224$12C+,C+,24C+,C+, V3S96G- V4S96G-"
      DATA "T24$12G+,G+,24G+,G+, V224$12C+,C+,24C+,C+, V3S48C.24G- V4S48C.24G-"
      DATA "T24$G+,$G+, V224$C+,$C+, V3S24C12B-CDEFG V4S24C12B-CDEFG"
      DATA "T24$12A+,A+,24A+,A+, V224$12E+&,E+&,24E+&,E+&, V3S48F.24A- V4S48F.24A-"
      DATA "T24$12F+#,F+,24F+,F+, V224$12C+,C+,24C+,C+, V3S48C24B-C V4S48C24B-C"
      DATA "T24$12G+,G+,24$12G+,G+, V224$12C+,C+,24$12C+,C+, V3S48EC V4S48EC"
      DATA "T24$12G+,G+,24$12G+,G+, V224$12F+,F+,24$12F+,F+, V3S48FB V4S48FB"
      DATA "T24C++12B+,A+,G+,F+,E+,D+, V224E+ V3S24C12B,A,G,F,E,D, V4S24C12B,A,G,F,E,D,"
      DATA "PJ"
      DATA "T24C+,12C++,C++,24C++$ V224$12G+,G+,24G+$ V3S24C,12C,C,24C$ V4S24C,12C,C,24C$"
      
      DATA "; Trio (RTR 2023)"
      DATA "K1b"
      DATA "TV1 24$48F,24F V2 24$48C,24C V3 24$48A-,24A- SV4 48F.24E"
      DATA "TV1 24$A48$ V2 24$C48$ V3 24$A-48$ SV4 24DC12DCDE"
      DATA "TV1 24$48F,24F V2 24$48C,24C V3 24$48A-,24A- SV4 48F.24E"
      DATA "TV1 24$A48$ V2 24$C48$ V3 24$A-48$ SV4 24DC12DCDE"
      DATA "TV1 96A-48B-B%- SV3 24F-48F,24F-FF-F V4 24$48C,24C$C$C"
      DATA "TV1 96C48DE SV2 24$48A,24A$A$A V3 24F-48F,24FF-FF-F V4 24$48C,24C$C$C"
      DATA "TV1 96F48EbDb  SV2 24$48Ab,24Ab$Ab$Ab V3 24$48F,24F$F$F V4 24Db-48Db,24DbDb-DbDb-Db"
      DATA "TV1 144C'48C   SV2 24$48A%,24A%$A%$A% V3 24$48F,24F$F$F V4 24F-48C,24CF-CF-C"
      DATA "TV1 96D'48D,Db V2 96$48B,B SV3 24$48B,24B$B$B V4 24B-48F,24FB-FB-F"
      DATA "TV1 144C'48C   V2 96A48GF  SV3 24$48A,24A$A$A V4 24C48F,24FCFCF"
      DATA "TV1 96A48GF#   SV2 24$48B%,24B$B$B V3 24$48G,24G$G$G V4 24G-$$$G-$G-$"
      DATA "TV1 48AGE24DDb SV2 24$48B, 24B$B$B V3 24$G$G$G$G     V4 24CECEC$C$"
      DATA "TV1 96A48BB%   SV2 96A-48B-B%-     V3 24$48F,24F$F$F V4 24F-48C,24CF-CF-C" : REM Bars 21-22
      DATA "TV1 96C+48D+E+ SV2 96C48DE         V3 24$48F,24F$F$F V4 24F-48C,24CF-CF-C"
      DATA "TV1 96F+48G+G+#  SV2 24$48D+b,24D+$$$B% V3 24Db48Ab,24AbDbB%DbB% V4 24Db-48F,24FDb-FDb-F"
      DATA "TV1 96A+48F+,F+  SV2 24$48C,24C$C$C     V3 24C48A,24A$A$A        V4 24C-48F,24FF-FA-F"
      DATA "TV1 96A+b48G+F+  SV2 24$48D+,24D+$D+$D+ V3 24B%-48G#,24G#B%-G#B%-G# V4 24B%-48F,24FB%-FB%-F"
      DATA "TV1 48D++C++A+F+ SV2 24$C+$C+$C+$C+     V3 24CACACACA            V4 24C-FC-FC-FC-F"
      DATA "TV1 48G+D+E+G+   SV2 24$B%$B%$C+$C+     V3 24$G$GCBCB            V4 24G-FG-FC-GC-G" : REM Bars 33-34
      DATA "TV1 120F+12A+,A+,24A+,A+ SV2 24$48C+,24C+,C+ V3 24$48A,24A,A V4 24F-48F,24F,F$$$"
      DATA "TV1 8E+A+E+A+E+A+E+A+E+A+E+A+ V2 8C+#$C+#$C+#$C+#$C+#$C+#$ SV3 24A,12AB%C+C+#D+D+#"
      DATA "TV1 8E+A+E+A+E+A+E+A+E+A+E+A+ V2 8C+#$C+#$C+#$C+#$C+#$C+#$ SV3 12E+$24E+C#+A"
      DATA "TV1 8F+A+E+A+F+A+E+A+F+A+E+A+ V2 8D+$A$D+$A$D+$A$ SV3 24F+12E+D+C#+D+E+C+"
      DATA "TV1 8E+A+E+A+E+A+E+A+E+A+E+A+ V2 8C+#$C+#$C+#$C+#$C+#$C+#$ SV3 24AB48A"
      DATA "TV1 8C+C++C+C++C+C++C+C++C+C++C+C++ V2 8E+$E+$E+$E+$E+$E+$ V3 24C,12CC#DEFF#"
      DATA "TV1 8C+C++C+C++C+C++C+C++C+C++C+C++ V2 8E+$E+$E+$E+$E+$E+$ V3 12G$24GEC"
      DATA "TV1 8C+C++C+C++C+C++C+C++C+C++C+C++ V3 24B12F#A24GC"
      DATA "TV1 8C+C++C+C++C+C++C+C++C+C++C+C++ V3 24B12F#A24GC V4 24B12F#A24GC"
      DATA "TV1 8C+C++C+C++C+C++C+C++C+C++C+C++ SV3 12CC#DD#EFF#G V4 12C-C#-D-D#-E-F-F#-G-"
      DATA "TV1 8C+C++C+C++C+C++C+C++C+C++C+C++ SV3 24G#ABB% V4 24G#-A-B-B%-"
      
      DATA "=130"
      DATA "TV1 6$90A+48B+B%+   V2 3$93F+48BB%  V3 96C+S24$F+$F+ SV4 24F-12F,F24F-,F24F-FF-F"
      DATA "TV1 6$90C++48D++E++ V2 3$93A+48D+E+ V3 96F+S24$F+$F+ SV4 24F-12F,F24F-,F24F-FF-F"
      DATA "TV1 96F++ V2 96F+ SV3 24Db12Db+,Db+,24Db+,Db+ V4 24Db-12F,F,24F,F,"
      DATA "TV1 48Eb++Db++ V2 48Eb+Db+ SV3 24DbDb+DbDb+ V4 24Db-FDb-F"
      DATA "TV1 6$138C++'48C++ V2 3$141A+'48F+ V3 144F+24F-F SV4 24F-12A,A,24A,AF-AF-A"
      DATA "TV1 96D++     V2 96D+    SV3 24B-12D+,D+,24D+,D+ V4 24B-12F,F,24F,F,"
      DATA "TV1 48B++,B++ V2 48B+,B+ SV3 24B-D+B-D+b         V4 24B-FB-F"
      DATA "TV1 96A++     V2 96A+    SV3 24C12C+,C+,24C+,C+  V4 24C-12F,F,24F,F"
      DATA "TV1 48G++F++  V2 48G+F+  SV3 24CC+CF+            V4 24C-FC-A"
      DATA "TV1 96A++     V2 96A+    SV3 24G12F+,F+,24F+,F   V4 24B%-12B%,B%,24B%,B%"
      DATA "TV1 48G++F#++ V2 48G+F#+ SV3 24GB%GB%            V4 24G-GG-G"
      DATA "TV1 48A++G++  V2 48A+G+  SV3 24CE+CE+            V4 24C-GC-G"
      DATA "TV1 48E++24D++Db++ V2 48E+24D+Db+ SV3 24CE+CE+   V4 24C-GC-G"
      DATA "TV1 96A+ V2 96A SV3 24F12F+,F+,24F+,F+ V4 24F-12C,C,24C,C"
      DATA "TV1 48B+B%+ V2 48BB% SV3 24FF+FF+ V4 24F-AF-A"
      DATA "TV1 6$90C++ V2 3$93A+ V3 96F+ SV4 24F-12A,A,24A,A"
      DATA "TV1 48D++E++ V2 48D+E+ SV3 24FF+FF+ V4 24F-AF-A"
      DATA "TV1 96F++ V2 96F+ SV3 24Db12F,F,24F,F V4 24Db-12Ab,Ab,24Ab,Ab"
      DATA "TV1 48G++G#++ V2 48G+G#+ SV3 24GF+GF+ V4 24G-BG-B"
      DATA "TV1 96A++ V296A+ SV3 24C12F+,F+,24F,F V4 24C-12C,C,24C,C"
      DATA "TV1 48F++'F++ V2 48F+'F+ SV3 24A-F+A-F+ V4 A-C+A-C+"
      DATA "TV1 96F++ V2 96F+ SV3 24G#-12B%,B%,24B%,B% V4 24G#12G,G,24G,G"
      DATA "TV1 48E++D++' V2 48E+D+' SV3 24G#-F+B%-F+ V4 24G#GB%--G"
      DATA "TV1 48D++C++  V2 48D+C+  SV3 24CF+CF+ V4 24C-AC-A"
      DATA "TV1 48F++A+   V2 48F+A   SV3 24CF+CF+ V$ 24C-AC-A"
      DATA "TV1 144C++'48C++ V2 144A+48G+ V3 144C+'48C+ SV4 24C12E+,E+,24E+,E+CE+CB"
      DATA "TV1 24F++12E++G++24F++12E++G++ V2 24F+12E+G+24F+12E+G+ SV3 24FD+bCD+b V4 24F,F,F,F"
      DATA "TV1 24F++$F++$ V2 24F+$F+$ SV3 24C+$F+$ V4 24C++$F++$"
      
      DATA "255$"
      DATA ""